Visual Basic（.NET2002以降）¶

Dim id As Integer
Dim result As Integer

Private Sub ResultShow(ByVal title As String, ByVal resultCode As Integer)
    Dim resultString As New StringBuilder(256)
    YdxCnvResultToString(resultCode, resultString)
    Select Case resultCode
        Case 0, Ydx.YDX_RESULT_DI_EXCEED_DATA_NUM, Ydx.YDX_RESULT_DI_EXCEED_BUF_SIZ
            MessageBox.Show(resultString.ToString(), title, MessageBoxButtons.OK, MessageBoxIcon.Asterisk)
        Case Else
            MessageBox.Show(resultString.ToString(), title, MessageBoxButtons.OK, MessageBoxIcon.Hand)
    End Select
End Sub

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
    ' ユニット識別スイッチ
    unitSwitchComboBox.ResetText()
    unitSwitchComboBox.Items.AddRange(New String() { "0", "1", "2", "3", "4", "5", "6", "7", "8", "9", "A", "B", "C", "D", "E", "F" })
    unitSwitchComboBox.SelectedIndex = 0

    ' 型名
    modelNameComboBox.ResetText()
    modelNameComboBox.Items.AddRange(New String() { "DIO-16/16C-USC", "DIO-16/16D-UBC", "DIO-16/16D-USC" })
    modelNameComboBox.SelectedIndex = 0
End Sub

Private Sub openButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles openButton.Click
    result = YdxOpen(unitSwitchComboBox.SelectedIndex, modelNameComboBox.Text, 0, id)
    If result <> 0 Then
        ResultShow("YdxOpen", result)
    Else
        unitSwitchComboBox.Enabled = False
        modelNameComboBox.Enabled = False
        ResultShow("オープン", result)
    End If
End Sub

Private Sub startButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles startButton.Click
    ' データバッファの設定
    result = YdxDoSetBuffer(id, 0) ' FIFOバッファ
    If result <> 0 Then
        ResultShow("YdxDoSetBuffer", result)
        Exit Sub
    End If

    ' チャネルの設定
    For channel As Integer = 0 To 15
        result = YdxDoSetChannel(id, channel, 1) ' 高機能デジタル出力モード
        If result <> 0 Then
            ResultShow("YdxDoSetChannel", result)
            Exit Sub
        End If
    Next

    ' サンプリングクロックの設定
    result = YdxDoSetClock(id, 0)    ' 内部クロック
    If result <> 0 Then
        ResultShow("YdxDoSetClock", result)
        Exit Sub
    End If

    ' 内部クロック周期の設定
    result = YdxDoSetClockInternal(id, 1000) ' 1000μsec
    If result <> 0 Then
        ResultShow("YdxDoSetClockInternal", result)
        Exit Sub
    End If

    ' データの設定
    Const SAMPLE_NUM As Integer = 1000  ' サンプル数
    Dim data(SAMPLE_NUM) As Integer
    For i As Integer = 0 To SAMPLE_NUM - 1
        data(i) = i
    Next
    result = YdxDoSetData(id, SAMPLE_NUM, data)
    If result <> 0 Then
        ResultShow("YdxDoSetData", result)
        Exit Sub
    End If

    ' サンプリング開始条件の設定
    result = YdxDoSetStartCondition(id, 0, 0)   ' ソフトウェア
    If result <> 0 Then
        ResultShow("YdxDoSetStartCondition", result)
        Exit Sub
    End If

    ' サンプリング停止条件の設定
    result = YdxDoSetStopCondition(id, 0, 0)    ' データ終了
    If result <> 0 Then
        ResultShow("YdxDoSetStopCondition", result)
        Exit Sub
    End If

    ' デジタル出力動作を開始
    result = YdxDoStart(id)
    If result <> 0 Then
        ResultShow("YdxDoStart", result)
        Exit Sub
    End If

    ' 動作終了待ち
    Dim status, sampleCount, repeatCount, notOutNum As Integer
    '動作中ステータスがOFFになるまでポーリング
    Do
        Application.DoEvents()

        'ステータスの取得
        result = YdxDoGetStatus(id, status, sampleCount, repeatCount, notOutNum)
        If result <> 0 Then
            ResultShow("YdxDoGetStatus", result)
            Exit Sub
        End If
        statusTextBox.Text = status.ToString("X").PadLeft(8, "0"c) & "h"
        sampleCountTextBox.Text = sampleCount.ToString()
        repeatCountTextBox.Text = repeatCount.ToString()
        notOutNumTextBox.Text = notOutNum.ToString()

        if(status And YDX_STATUS_COMMUNICATE_ERR) <> 0 Then
            MessageBox.Show("通信エラーが発生しました", "", MessageBoxButtons.OK, MessageBoxIcon.Hand)
            Exit Sub
        End If
        if(status And YDX_STATUS_HARDWARE_ERR) <> 0 Then
            MessageBox.Show("ハードウェアエラーが発生しました", "", MessageBoxButtons.OK, MessageBoxIcon.Hand)
            Exit Sub
        End If
        if(status And YDX_STATUS_SAMPLE_CLOCK_ERR) <> 0 Then
            MessageBox.Show("サンプリングクロックエラーが発生しました", "", MessageBoxButtons.OK, MessageBoxIcon.Hand)
            Exit Sub
        End If
    Loop While(status And YDX_STATUS_BUSY) <> 0
    ResultShow("出力", 0)
End Sub

Private Sub closeButton_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles closeButton.Click
    unitSwitchComboBox.Enabled = True
    modelNameComboBox.Enabled = True
    result = YdxClose(id)
    If result <> 0 Then
        ResultShow("YdxClose", result)
    Else
        ResultShow("クローズ", result)
    End If
End Sub

Private Sub Form1_Closing(ByVal sender As Object, ByVal e As System.ComponentModel.CancelEventArgs) Handles MyBase.Closing
    result = YdxClose(id)
    If result <> 0 And result <> YDX_RESULT_NOT_OPEN Then
        ResultShow("YdxClose", result)
    End If
End Sub